2013-06-18 23:35

/* This creates a Main Window with a Group of 1 ENTRY with the REPORT
 * flag set.  Whenever the user types into the ENTRY and presses ENTER,
 * RXMSG returns, and we force the ENTRY to contain the string "hello".
 */

ADDRESS null

/* Trap HALT and SYNTAX in any scripts we call which don't
 * trap HALT or SYNTAX themselves.
 */
OPTIONS 'TRAP'

/* Trap SYNTAX/ERROR/HAT, and ask for ERROR raising */
SIGNAL ON HALT
SIGNAL ON SYNTAX
SIGNAL ON ERROR
CALL RXERR('ERROR|DISPLAY')



/* =============== Create "Main Window" ================= */
/* First Group is ENTRY */
rxtype.1 = 'ENTRY'

/* Use of a control in this group causes RXMSG to return */
rxflags.1 = 'REPORT'

/* Label for control. No Groupbox */
rxlabel.1 = 'Type Here:|'

/* REXX variable where initial text stored */
rxval.1 = 'STRS'

/* ControlsPerLine, X Position, Y Position, Width */
rxpos.1 = '1 10 10 90'

/* Text */
strs.1 = 'some stuff'

/* Default size and position */
rx = ''

/* NOCLOSE since we want to close the window ourselves. No
 * RESULT Flag, so the ESC and ENTER keys do nothing, and
 * we don't have to bother checking for those
 */
CALL RXCREATE('RX', 1, 'RXSET() VALUE -- ENTRY', 'NOCLOSE|SIZE')

DO FOREVER

/* Do user interaction */
CALL RXMSG()

/* Did user click upon the CLOSE BOX? If so, then exit */
IF rxid == '' THEN SIGNAL HALT

/* Since there is only 1 group and 1 control, we know that it
 * caused RXMSG to return. Force contents of ENTRY to 'hello'
 */
CALL RXSET(, 'VALUE', 'hello', 1, 1)

END /* DO FOREVER */



/* ==================== Error Handling ====================== */
syntax:
    CALL RXSAY(CONDITION('D') || '0D0A0D0A'x || SOURCELINE(sigl),,'Error '||condition('E')||' at line '||sigl)

halt:
error:
    /* NOTE: CONDITION('D') fetches error message. CONDITION('E') fetches the
     * error number. SIGL is the line number where the error occurred.
     * Rexx Dialog has already displayed a message since we specified DISPLAY
     * option.
     */
    CALL RXMSG(,'END')
    EXIT

2013-06-18 23:35