2013-06-18 23:35

/* This creates a Main Window with a Group of 1 single-select LIST with the
 * REPORT flag set.  Whenever the user makes a selection in the LIST, RXMSG
 * returns, and we force the selection to the "hello" item.
 */

/* Toss away the return from a function if
 * we don't assign it to a variable
 */
ADDRESS null

/* Trap HALT and SYNTAX in any scripts we call which don't
 * trap HALT or SYNTAX themselves.
 */
OPTIONS 'TRAP'

/* Trap SYNTAX/ERROR/HAT, and ask for ERROR raising */
SIGNAL ON HALT
SIGNAL ON SYNTAX
SIGNAL ON ERROR
CALL RXERR('ERROR|DISPLAY')

/* =============== Create "Main Window" ================= */
/* First Group is LIST */
rxtype.1 = 'LIST'

/* Use of a control in this group causes RXMSG to return */
rxflags.1 = 'REPORT'

/* Label for control. No Groupbox */
rxlabel.1 = 'Force to Hello:|'

/* REXX variable where initial text stored */
rxval.1 = 'STRS'

/* ControlsPerLine, X Position, Y Position, Width, Height (NumOfVisibleItems) */
rxpos.1 = '1 8 8 90 6'

/* Text */
strs.1 = 'some stuff'
strs.2 = 'hi'
strs.3 = 'hello'
strs.4 = 'blort'
strs.5 = ''

/* Default size and position */
rx = ''

/* NOCLOSE since we want to close the window ourselves.
 * No RESULT Flag, so the ESC and ENTER keys do nothing,
 * and we don't have to bother checking for those
 */
CALL RXCREATE('RX', 1, 'RXSET() VALUE -- LIST', 'NOCLOSE')

DO FOREVER

/* Do user interaction */
CALL RXMSG()

/* Did user click upon the CLOSE BOX? If so, then exit */
IF rxid == '' THEN SIGNAL HALT

/* Since there is only 1 group and 1 control, we know that it
 * caused RXMSG to return. Force selection of 'hello' item.
 */
CALL RXSET(, 'VALUE', 'hello | 1', 1, 1)

END /* DO FOREVER */



/* ==================== Error Handling ====================== */
syntax:
    CALL RXSAY(CONDITION('D') || '0D0A0D0A'x || SOURCELINE(sigl),,'Error '||condition('E')||' at line '||sigl)

halt:
error:
    /* NOTE: CONDITION('D') fetches error message. CONDITION('E') fetches the
     * error number. SIGL is the line number where the error occurred.
     * Rexx Dialog has already displayed a message since we specified DISPLAY
     * option.
     */
    CALL RXMSG(,'END')
    EXIT

2013-06-18 23:35