@ECHO OFF
REM
REM Change the paths according to your drive/system/programs
REM If you don't have FreeBASIC, and will use the supplied dll
REM just ignore any lines referring to FreeBASIC
REM FreeBasic v0.20.0 Beta or latest v0.21.0 have been tested.
REM
SET FB=c:\FreeBASIC\fbc.exe
SET RQ=c:\rapidq\rc.exe
SET INC_PATH=c:\rapidq\inc
SET LIB_PATH=c:\rapidq\lib
REM Project source filenames
SET DLL_SRC=fbDBGParser.fbb
SET BAS_SRC=RapidDBG.bas
REM
REM Start compiles
REM
IF NOT EXIST "%FB%" GOTO DOBAS
IF NOT EXIST "%DLL_SRC%" GOTO ERROR_DLL_SRC
ECHO Compiling %DLL_SRC%
%FB% -version
%FB% -s gui -dll -w 2 -b %DLL_SRC%
IF ERRORLEVEL 1 GOTO ERROR_DLL
REM Cleanup FreeBASIC unwanted file
DEL *.dll.a
ECHO -----------------------------------
ECHO  FreeBASIC dll created ok!
ECHO -----------------------------------
:DOBAS
%RQ% -I%INC_PATH% -L%LIB_PATH% %BAS_SRC%
IF ERRORLEVEL 1 GOTO ERROR_COMP
ECHO ----------------------------------
ECHO  RapidDBG Debugger created ok!
ECHO ----------------------------------
GOTO DONE
:ERROR_DLL_SRC
ECHO !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
ECHO ! %DLL_SRC% does not exist    !
ECHO !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
GOTO DONE
:ERROR_DLL
ECHO !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
ECHO ! %DLL_SRC% FAILED compile    !
ECHO !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
GOTO DONE
:ERROR_COMP
ECHO !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
ECHO ! %BAS_SRC% FAILED compile   !
ECHO !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
:DONE
REM Remove our temp environment variables
SET FB=
SET RQ=
SET INC_PATH=
SET LIB_PATH=
SET DLL_SRC=
SET BAS_SRC=
PAUSE