/*
GUIBEGIN
WINDOW , 53, 175, 363, 138,  POPUP|CAPTION|SYSMENU|MINBOX|MAXBOX|THICK,  , Menu demo
  FONT 8, 400, MS Shell Dlg
  MENU
  PUSH 9, 7, 55, 17, TABSTOP, , AddFname, , Add filename
DEND

MENU
  HEADING &Test
    ITEM C:\\MyDir\\MyFile, , , ID
    ITEM E:\\MyDir\\My Directory\\MyFile2, , , ID
  <
DEND
GUIEND
*/

/* This example demonstrates the ID option for a menu item. When it has the
 * ID option, then whenever the user selects the item, then the window's
 * WM_MENUID event handler is called. ARG(1) is the ID (number of the
 * item selected. (This number depends upon when the item was added to the
 * menu. Items added last have the highest ID numbers). ARG(2) is the menu
 * caption.
 */
LIBRARY rexxgui
guierr = "SYNTAX"
guiheading = 1
guicreatewindow('NORMAL')
again:
DO FOREVER
  guigetmsg()
  CATCH SYNTAX
    CONDITION('M')
    SIGNAL again
  FINALLY
    guidestroywindow()
END
RETURN

wm_menuid:
  guisay("ID =" ARG(1) || '0D0A'x || ARG(2))
  RETURN

wm_click_addfname:
  /* Add an item at a position of 1 3.
   *
   * The item has a caption of "A:\MyDir\My Floppy File", and has the
   * ID option.
   */
  guiaddmenu("A:\MyDir\My Floppy File, , , ID", "ITEM", "1 3")

  /* Disable the button so he can't click it again. */
  guisetctlplacement("AddFname", , , , , "DISABLE")
  RETURN