2010-07-16 20:48

/*
GUIBEGIN
WINDOW , 0, 0, 268, 60, DOCK|BOTTOM|EMBED|CAPTION|SYSMENU, , My Help Window
	HTML 10, 0, 24, 21, , , MyBrowser
DEND
GUIEND
*/

/* This child script simply displays an HTML page in a docking window
 * that contains an HTML control (which fills the docking window).
 *
 * It is assumed that the creator passes two extra args to CreateObject --
 * the parent window handle, and a URL to display in our HTML control.
 */

create:
	guierr = "SYNTAX"
	guiheading = 1

	/* Stuff the caller's URL into the variable associated with our
	 * HTML control. When our window opens, it will display this URL.
	 */
	mybrowser = ARG(2)

	/* Create a docked window, with the caller's window as owner. */
	guicreatewindow("NORMAL", ARG(1))

	RETURN

/* Called by the parent to change the URL displayed. This is called
 * when our child window is already open.
 */
seturl:
	mybrowser = ARG(1)
	guisetctlvalue("MyBrowser")
	RETURN

destroy:
	guidestroywindow()
	RETURN

wm_size:
	/* Resize the HTML control so that it fills our window. We do this
	 * by calling GuiSetCtlPlacement, with the same X, Y, Width and Height
	 * as our size event now. But don't do this until the HTML control
	 * is finally created (ie, SIZE events can happen for the window
	 * before its controls are created).
	 */
	IF guiinfo("HANDLE", "MyBrowser", 2) \== "" THEN
		guisetctlplacement("MyBrowser", ARG(1), ARG(2), ARG(3), ARG(4))
	RETURN ""

2010-07-16 20:48